OKCoin

区块链技术(三):智能合约入门

蓝莲花 发布在 技术指南 2 13572

文章摘要图:

区块链技术(三):智能合约入门_meitu_1

一个简单的智能合约

先从一个非常基础的例子开始

1
2
3
4
5
6
7
8
9
10
11
12
contract ZhaoxiStorage {

    uint storedData;

    function set(uint x) {
        storedData = x;
    }

    function get() constant returns (uint retVal) {
        return storedData;
    }
}

在Solidity中,一个合约由一组代码(合约的函数)和数据(合约的状态)组成。合约位于以太坊区块链上的一个地址。

uint storedData; 这行代码声明了一个状态变量,变量名为storedData,类型为无符号整数uint。可以看做数据库里面的一条记录,可以通过调用函数查询和修改它。在以太坊中,通常只有合约的拥有者才能这样做。在这个例子中,函数 set 和 get 分别用于修改和查询变量的值。

跟很多其他语言一样,访问状态变量时,不需要在前面增加 this. 这样的前缀。

任何人都可以调用set方法设置一个不同的数字覆盖你发布的数字。但是你的数字将会留存在区块链的历史上。稍后我们会学习如何增加存取限制。

一个加密货币例子

接下来的合约将实现一个形式最简单的加密货币。通过这份代码,任何人都可以发送货币给其他人,不需要注册用户名和密码,只要有一对以太坊的公私钥即可。

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
contract ZhaoxiCoin {

    // 关键字“public”使变量能从合约外部访问。
    address public minter;
    mapping (address => uint) public balances;

    // 事件让轻客户端能高效的对变化做出反应。
    event Sent(address from, address to, uint amount);

    // 这个构造函数的代码仅仅只在合约创建的时候被运行。
    function ZhaoxiCoin() {
        minter = msg.sender;
    }

    // 合约创建者可以调用mint
    function mint(address receiver, uint amount) {
        if (msg.sender != minter) return;
        balances[receiver] += amount;
    }

    // send可以被拥有代币的任何人调用
    function send(address receiver, uint amount) {
        if (balances[msg.sender] < amount) return;
        balances[msg.sender] -= amount;
        balances[receiver] += amount;
        Sent(msg.sender, receiver, amount);
    }
}

address public minter 这行代码声明了一个可公开访问的状态变量,类型为address。address类型的值大小为160 bits,适用于存储合约的地址或其他人的公私钥。public关键字会自动为其修饰的状态变量生成访问函数。没有public关键字的变量将无法被其他合约访问。另外只有本合约内的代码才能写入。自动生成的函数如下:

1
function minter() returns (address) { return minter; }

下一行代码mapping (address => uint) public balances; 创建了一个public的状态变量,但是其类型更加的复杂。该类型将一些address映射到无符号整数。mapping可以被认为是一个哈希表,每一个可能的key对应的value被虚拟的初始化为全0。对于一个mapping,无法获取一个包含其所有key或者value的链表。所以我们得自己记着添加了哪些东西到mapping中。在这个例子中由public关键字生成的访问函数将会更加复杂,其代码大致如下:

1
2
3
function balances(address _account) returns (uint balance) {
    return balances[_account];
}

event Sent(address from, address to, uint value)这行代码声明了一个“事件”。由send函数的最后一行代码触发。客户端可以监听这些由区块链触发的事件。事件触发时,监听者会同时接收到from,to,value这些参数值,可以方便的用于跟踪交易。为了监听这个事件,你可以使用如下代码:

1
2
3
4
5
6
7
8
9
10
ZhaoxiCoin.Sent().watch({}, '', function(error, result) {
    if (!error) {
        console.log("ZhaoxiCoin transfer: " + result.args.amount +
            " coins were sent from " + result.args.from +
            " to " + result.args.to + ".");
        console.log("Balances now:\n" +
            "Sender: " + ZhaoxiCoin.balances.call(result.args.from) +
            "Receiver: " + ZhaoxiCoin.balances.call(result.args.to));
    }
}

这里有个比较特殊的函数 ZhaoxiCoin。它是一个构造函数,会在合约创建的时候运行,之后就无法被调用。它会永久得存储合约创建者的地址。msg(以及tx和block)是一个全局变量,它包含了一些可以被合约代码访问的属于区块链的属性。msg.sender 总是存放着当前函数的外部调用者的地址。

最后,真正被用户或者其他合约调用,用来完成本合约功能的函数是mint和send。如果合约创建者之外的其他人调用mint,什么都不会发生。而send可以被任何人(拥有一定数量的代币)调用,发送一些币给其他人。

以上就是一个简单的加密货币的完整代码和说明。

*提示:代码格式显示有问题的话,请访问原文:http://wangxiaoming.com/blog/2016/05/03/blockchain-tech-introduciton-to-smart-contracts/

发文时比特币标准价格 买价:¥2933.93 卖价:¥2930.99
关于我:网名蓝莲花,原名汪晓明,微信/QQ:263305605,公众号:xm123798。朝夕网络(zhaoxi.co)合伙人。致力于推动区块链行业发展,推广区块链解决方案。
比特币地址:1FTefJd3ZHtgeVkDAqKEAx5GkjizyeaDiw
原文:http://wangxiaoming.com/blog/2016/05/03/blockchain-tech-introduciton-to-smart-contracts/
版权声明: by nc" sa 作者保留权利。文章为作者独立观点,不代表巴比特立场。

评论:2

您需要登录后才可以回复 登录|注册